Msg function

Displays dynamically constructed system messages.

variablereturn = Msg(ownerwindow, msgstructure, msgname, reserved, parameters)

The Msg function has the following parameters.

Note: The Msg function resets the Set_Status() code to zero (0).

Use Msg either for display messages (i.e. error handling) or use it for gathering very small scale user input, as for example with Continue? Yes No situations.

The return value depends on the value passed for the type field of the msgstructure argument.

Note: If you are trying to use the MSG function and the variable you are trying to display contains any system delimiters it may not display correctly. (for example, a message box or button may display with garbled text or won't function properly) What you need to do is use either the CONVERT or SWAP statements. For example:

CONVERT @fm to ',' in VarName

-or-

SWAP @fm with ', ' in VarName

Your message box should now display correctly.

Use the MSG_EQUATES insert record for access to the values in the following table.

Msg() return values are indicated in the following table.

Example 1: request the user's password (and return it uppercased)

Def = ""

Def<MTEXT$> = "Enter your password:"

Def<MTYPE$> = "RCE"

Def<MICON$> = "?"

Def<MMASKINPUT$> = TRUE$

 

Password = Msg(@window, Def)

if Password = char(27) then

   * user escaped from the message

end else

   * user supplied password (which could be null) and pressed enter

end

Example 2: display a message stored in the repository as "ERROR_MESSAGE"

Text = "An error occurred opening the table for processing."

Msg(@window, Text, "ERROR_MESSAGE")

Example 3: display a message while batch processing

Def = ""

Def<MTEXT$> = "Processing..."

Def<MTYPE$> = "U"

* display the processing message and do the processing

MsgUp = Msg(@window, Def)

gosub BatchProcess

* take down the processing message

Msg(@window, MsgUp)

Example 4: display a gas gauge to show progress while processing 1000 orders

$insert msg_equates

OrderCnt = 1000

Def = ""

Def<MCAPTION$> = "Processing Orders..."

Def<MTYPE$   > = "GC"

Def<MEXTENT$ > = OrderCnt

Def<MTEXTWIDTH$ > = 400

MsgUp = Msg(@window, Def)

for Order = 1 to OrderCnt

    /*  process the order */

    * update the gauge and check if cancel was pressed

while Msg(@window, MsgUp, Order, MSGINSTUPDATE$)

next Order

/*  we are done, take down the gas gauge */

Msg(@window, MsgUp)         ;* take down the gauge

Example 5: logon processing with a batch screen

Def = ""

Def<MTYPE$> = "TA5"

 

* display 5-second splash-screen while performing login processing

Msg(@window, Def, "SPLASHSCREEN")

gosub Logon_Process

* allow the message to close if 5 seconds have elapsed

Yield()

gosub Setup

Example 6: password response message using a peek time of 200 milliseconds

              Def ='' 

              Def<MTEXT$     > = "Enter Password"

              Def<MTYPE$     > = "RE"

              Def<MICON$     > = "?"

              Def<MCAPTION$  > = "Password Style Response"

              Def<MMASKINPUT$> = 1

              Def<MPWDPEEK$  > = 200

              MsgUp = Msg(@window, Def)

Example 7: response message with valid character being abcd1234

              Def =''

              Def<MTEXT$      > = "Valid characters are abcd1234"

              Def<MTYPE$      > = "RE"

              Def<MICON$      > = "!"

              Def<MCAPTION$   > = "Valid CHAR Response Message"

              Def<MVALIDCHARS$> = "abcd1234"

              MsgUp = Msg(@window, Def)

Example 8: response message with a date edit mask

              Def =''

              Def<MTEXT$      > = "Please enter date of response"

              Def<MTYPE$      > = "RE"

              Def<MICON$      > = "?"

              Def<MCAPTION$   > = "Edit Mask Response Message"

              Def<MMASKFORMAT$> = "__/__/____"

              Def<MMASKTYPE$  > = "dd dd dddd"

              MsgUp = Msg(@window, Def)

Example 9: display a message containing title text and html

              Def ='' 

              Def<MTEXT$    > = "<b>Processing using Title Text and HTML</b>"

              Def<MTYPE$    > = "U"

              Def<MCAPTION$ > = "Processing Message "

              Def<MHTML$    > = 1

              Def<MMAINTEXT$> = "Main Title Text"

              MsgUp = Msg(@window, Def)

              Delay(5)

              * take down the processing message

              Msg(@window, MsgUp)

Example 10: display a timed 'pop-up toast' type of message

              Def ='' 

              Def<MTEXT$   > = "Your file has been sent..."

              Def<MTYPE$   > = "T5"

              Def<MICON$   > = "*"

              Def<MCAPTION$> = "Timed 'Pop-up Toast' Message"

              Def<MPOPUP$  > = 1

              MsgUp = Msg(@window, Def)

Example 11: display a progress bar message

              Def ='' 

              Def<MTEXT$> = "Incudes Border, Taskbar Sync, Show Percentage Complete and Smooth options"

              Def<MTYPE$> = "GCY"

              Def<MICON$> = "*"

              Def<MCAPTION$> = "Progress Bar Message"

              Def<MGBORDER$> = 1

              Def<MGSMOOTH$> = 1

              Def<MGPERCOMPLETE$> = 1

              Def<MGSYNCTASK$> = 1

              Def<MGRANGESTART$> = 1

              Def<MGRANGEEND$> = 1000

              Def<MANIMATE$> = "FileCopyXP.avi"

              MsgUp = Msg(@window, Def)

              for i = Def<MGRANGESTART$> to Def<MGRANGEEND$>

                 * do processing here

                 Delay(4/Def<MGRANGEEND$>)

              While Msg(@Window, MsgUp, i, MSGINSTUPDATE$)

                 * get the state of the progress bar

                 state = Get_Property("MSG.EB_RESP", "STATE")

                 * if paused loop until state is changed

                 if state = 3 Then

                    loop

                       pause_status = Get_Property("MSG.EB_RESP", "STATE")

                    While pause_status = 3

                       call Yield()

                    Repeat

                 end

             next i

             * Clear progress on taskbar icon

             val = Set_Property("MSG.EB_RESP", "SYNCTASKBAR", 0)

             * we are done, take down the progress bar

             Msg(@window, MsgUp)

             Return

Example 12: display a vertical progress bar message

             Def ='' 

             Def<MTEXT$       > = "Vertical progress bar using the decrement option"

             Def<MTYPE$       > = "GCY"

             Def<MICON$       > = "!"

             Def<MTEXTWIDTH$  > = 500

             Def<MCAPTION$    > = "Progress Bar Vertical Message"

             Def<MGVERTICAL$  > = 1

             Def<MGRANGESTART$> = 1

             Def<MGRANGEEND$  > = 1000

             Def<MGDECREMENT$ > = 1

             MsgUp = Msg(@window, Def)

             for i = Def<MGRANGESTART$> to Def<MGRANGEEND$>

                * do processing here

                Delay(4/Def<MGRANGEEND$>)

             While Msg(@Window, MsgUp, i, MSGINSTUPDATE$, Def<MGDECREMENT$>) ;* pass in DECREMENT flag

                * get the state of the progress bar

                state = Get_Property("MSG.EB_RESP", "STATE")

                * if paused loop until state is changed

                if state = 3 Then

                   loop

                      pause_status = Get_Property("MSG.EB_RESP", "STATE")

                   While pause_status = 3

                      call Yield()

                   Repeat

                end

             next i

             * we are done, take down the progress bar

             Msg(@window, MsgUp)