Popup function

Displays tabular data and allows user selection.

Note: As of Version 4.1.3, the popup() function has been modified to sort dates and any other output converted data correctly.

result = Popup (ownerwindow, typeoverride[, name])

The Popup function has the following parameters:

Parameter	Description
ownerwindow	Contains the name of the window from which to display the specified popup, typically @WINDOW. Note: When using an MDIFrame, the ownerwindow will always be the frame regardless of the value passed to the variable. Caution: If there is no window, Popup will use the screen. In this case, there is no modality and no values will be returned to your program.
typeoverride	An @fm-delimited record containing the specification for the Popup, or override information if name is supplied.
name	The name of the Popup stored in the repository, or null if the entire Popup definition is being passed in typeoverride.

A popup can be called either by

Repository("EXECUTE", popupentID, window [, typeoverride]);

- OR -

Popup (window, typeoverride, popupname).

These column positions are defined in the POPUP_EQUATES insert record.

For a Popup with mode D, when the Popup is executed it determines what data source to use in this order.

1. If a DataSet handle is passed in <7, 2> (file), then that DataSet is used.

2. If a Connection Object handle is passed in <27, 2> (subfile), then the DataSet is created and executed using that handle.

3. If a DataSource name is passed in <27, 1> (subfile), then a connection handle is created for that DataSource name using XOInstance and that handle is used to create and execute the DataSet.

Otherwise, the DataSource name specified in the DataSet Designer is used to create a connection which in turn is used to create and execute the DataSet passed in <7, 1> (File).

POPUP_EQUATES (Insert record).

* Call a popup to Named 'EMP', fill in the EMP_NO control
* Use DEFPROP property, Send LOSTFOCUS event to trigger system events such as read or updating dependent controls
ans = popup(atWindow, '', 'EMP')
If ans Then
     Call Set_Property(atWindow:'.EMP_NO', 'DEFPROP', ans)
     Call Send_Event(atWindow:'.EMP_NO','LOSTFOCUS')
end

* Call a popup, override the definition to use a list of product keys related to this order

* Enable OI10 object notation for get, set property
#pragma precomp event_precomp

$insert popup_equates
declare subroutine send_Event
ctrl = atWindow:'.PRODUCT_CODE'
prod_codes = Xlate('ORDERS_REL', ordered, 'PRODUCTS', 'X')
override = ""
If prod_codes != null$ Then
     override<pMode$> = 'K' ; * list of keys
     override<pDisplay$> = prod_codes
     ans = popup(atWindow, override, 'SVC_CODE')
     If ans Then  
         @ctrl->DefProp = ans ; * same as set property
         Send_Event(object,'LOSTFOCUS')
    end
end

* Create a popup on the fly
* display a list stored in a user defined property

display = get_Property(atWindow, udp_route_list$)     
display_format = "1":@svm:"6":@svm:"R":@svm:"C":@svm:"":@SVM:"Route"

* Define the popup ( see POPUP_EQUATES )
def = ""
def<pTITLE$>     = 'Routes'
def<pMODE$>      = "L"                        ;* display will be literal data
def<pFORMAT$>    = display_format             ;* column format information (@vm delim'd by column, @svm by attribute) field, width, just, heading just, oconv, heading
def<pDISPLAY$>   = display                    ;* for mode 'L', the data to display, vm delimited by row, svm delimited by column
def<pGREENBAR$>  = true$                      ;* alternating colored rows in the display
def<pSEARCH$>    = true$                      ;* sortable
def<pSORT$>      = true$                      ;* searchable 
     
ans = Popup(atWindow, def)
If ans ne "" Then
     @CtrlEntID->Defprop = ans
     Call Send_Event(CtrlEntID, 'LOSTFOCUS')
end

* launch a popup next to the control
ctrl = atWindow:'.EF_FOR'
itemSize = @ctrl->Size
xPos = ( itemSize<1> + itemSize<3>)  ; * x + width
yPos = ( itemSize<2> )               ; * y

override = ""
override<pRow$> = yPos
override<pCol$> = xPos
ans = popup(atWindow, override, 'EMP')
If ans Then
     @ctrl->DefProp = ans
     Send_Event(ctrl,'LOSTFOCUS')
end